DotNET

.NET packages can be built with buildDotnetModule

More information about buildDotnetModule can be found in the nixpkgs manual Example build file:

{ fetchFromGitHub
, buildDotnetModule
}:

buildDotnetModule rec {
  pname = "some_program";
  version = "some_version";

  src = fetchFromGitHub {
    owner = "some_owner";
    repo = pname;
    rev = "v${version}";
    sha256 = "";
  };

  projectFile = "SomeProject/SomeProject.csproj";

  meta = with lib; {
    homepage = "some_homepage";
    description = "some_description";
    license = licenses.mit;
  };
}

Note that the above package will not build the first time. After adding the above definition to `all-packages.nix`, you can run the package-specific `fetch-deps` script, which will generate a file containing all the nuget dependencies of the package. Build the script with nix-build -A some-package.fetch-deps, copy that generated file (the location will be printed by the script) and set the nugetDeps attribute in buildDotnetModule to point to that generated file (ie. nugetDeps = ./deps.nix).

After that the package will build normally. Remember to re-run fetch-deps every time the package is updated.

Building non-.NET Core packages

Keep in mind that building non-.NET Core projects (ie. projects that don't build using the dotnet CLI tool) is not well supported. For those projects, you have to work on a custom derivation or override the buildDotnetModule build steps.

.NET location: Not found

If running a .NET-build executable you get the above error, make sure the DOTNET_ROOT environment variable is set:

environment.sessionVariables = {
  DOTNET_ROOT = "${pkgs.dotnet-sdk}/share/dotnet";
};

See : https://learn.microsoft.com/en-us/dotnet/core/tools/dotnet-environment-variables#net-sdk-and-cli-environment-variables

TargetFramework value was not recognized

error NETSDK1013: The TargetFramework value 'net6.0-windows' was not recognized. It may be misspelled. If not, then the TargetFrameworkIdentifier and/or TargetFrameworkVersion properties must be specified explicitly.

Wontfix: The project will build only on Windows.

NativeAOT

This is relevant for NixOS only.

nix-ld is needed:

{
  programs.nix-ld.enable = true;
}

Now we will need a bunch of native dependencies. Here's an example of a shell:

with import <nixpkgs> {};
pkgs.mkShell rec {

  dotnetPkg = 
    (with dotnetCorePackages; combinePackages [
      sdk_7_0
    ]);

  deps = [
    zlib
    zlib.dev
    openssl
    dotnetPkg
  ];

  NIX_LD_LIBRARY_PATH = lib.makeLibraryPath ([
    stdenv.cc.cc
  ] ++ deps);
  NIX_LD = "${pkgs.stdenv.cc.libc_bin}/bin/ld.so";
  nativeBuildInputs = [ 
  ] ++ deps;

  shellHook = ''
    DOTNET_ROOT="${dotnetPkg}";
  '';
}

Global Tools

Local installation of .NET global tools is fully supported and preferred when possible - more info in the Microsoft docs.

For globally installing .NET tools, search if they are available as Nix packages - they are packaged as any other normal .NET binary, using buildDotnetModule. For .NET tools with no source available, or those hard to build from source, buildDotnetGlobalTool is available. See dotnet nixpkgs manual for more info.

Note that Nix-packaged .NET tools use a special wrapper (toggled by useDotnetFromEnv option in buildDotnetModule) that automatically picks up .NET install from the user environment. If you want to use a different SDK version with a Nix-packaged .NET tools than the default, make sure the dotnet CLI of your wanted SDK version is installed and available.

Example: .NET Location Not Found

If having issues with global tools, here's an example of resolving the install location for sqlpackage

Install following .NET package

    pkgs.dotnetCorePackages.dotnet_8.sdk

Install global tool and replace user field

    dotnet tool install -g microsoft.sqlpackage
    export PATH="$PATH:/home/<user>/.dotnet/tools"
    sqlpackage

If fails, find the SDK location and export DOTNET_ROOT with SDK location (don't include /sdk)

    dotnet --list-sdks
    export DOTNET_ROOT="/nix/store/iv218glhk6id8pnbjykca9y2y1wrwc74-dotnet-sdk-8.0.108/share/dotnet/"

If having further issues, use following to provide further information

    export COREHOST_TRACE=1

Example: Running Rider with dotnet & PowerShell

Rider has better compatability when run in FHS mode

Rider package

pkgs.jetbrains.rider

rider-fhs.nix

{ pkgs ? import <nixpkgs> {} }:

(pkgs.buildFHSEnv {
  name = "rider-env";
  targetPkgs = pkgs: (with pkgs; [
    dotnetCorePackages.dotnet_8.sdk
    dotnetCorePackages.dotnet_8.aspnetcore
    powershell
  ]);
  multiPkgs = pkgs: (with pkgs; [
  ]);
  runScript = "nohup rider &";
}).env

nix-shell ./rider-fhs.nix

This can be added as an alias to your shell if you update the reference to an absolute address, such as location within your home directory. e.g. `~/nix/dotnet.nix`

Example: multi-SDK installation with local workload installation enabled

By default, workload installation will fail on NixOS, as dotnet will attempt to save it to $DOTNET_ROOT, which is inside the read-only Nix store.

Please visit the forum for an example of a multi-SDK installation with workload changed to install to home directory.

Navigation menu