View source for NixOS modules

NixOS produces a full system configuration by combining smaller, more isolated and reusable components: '''Modules'''. A module is a file containing a Nix expression with a specific structure. It ''declares'' options for other modules to ''define'' (give a value). It processes them and defines options declared in other modules.<ref>{{manual:nixos|sec=#sec-writing-modules|chapter=Chapter 42. Writing NixOS Modules}}</ref>

For example, {{ic|/etc/nixos/configuration.nix}} is a module. Most other modules are in {{Nixpkgs Link|nixos/modules}}.

Modules were introduced to allow extending NixOS without modifying its source code.<ref>[https://nixos.org/nix-dev/2008-November/001467.html <nowiki>[Nix-dev] NixOS: New scheme</nowiki>]</ref> They also allow splitting up {{ic|configuration.nix}}, making the system configuration easier to maintain and to reuse.

== Structure ==

Modules have the following syntax:

<syntaxhighlight lang="nix">
{
  imports = [
    # Paths to other modules.
    # Compose this module out of smaller ones.
  ];

  options = {
    # Option declarations.
    # Declare what settings a user of this module can set.
    # Usually this includes a global "enable" option which defaults to false.
  };

  config = {
    # Option definitions.
    # Define what other settings, services and resources should be active.
    # Usually these depend on whether a user of this module chose to "enable" it
    # using the "option" above. 
    # Options for modules imported in "imports" can be set here.
  };
}
</syntaxhighlight>

=== Function ===

A module can be turned into a function accepting an attribute set.

<syntaxhighlight lang="nix">
{ config, pkgs, ... }:
{
  imports = [];
  # ...
}
</syntaxhighlight>

It may require the attribute set to contain:

<dl>

<dt>[[NixOS:config_argument|<code>config</code>]]</dt>
<dd>The configuration of the entire system.</dd>

<dt><code>options</code></dt>
<dd>All option declarations refined with all definition and declaration references.</dd>

<dt><code>pkgs</code></dt>
<dd>The attribute set extracted from the Nix package collection and enhanced with the <code>nixpkgs.config</code> option.</dd>

<dt><code>modulesPath</code></dt>
<dd>The location of the <code>module</code> directory of NixOS.</dd>

</dl>

=== Imports ===

Imports are paths to other NixOS modules that should be included in the evaluation of the system configuration. A default set of modules is defined in {{Nixpkgs Link|nixos/modules/module-list.nix}}. These don't need to be added in the import list. 
==== Example ====
<syntaxhighlight lang="nix">
{
  imports = [
    # Paths to other modules.
    
    # They can be relative paths 
    ./otherModule.nix
    
    # Or absolute
    /path/to/otherModule.nix
  ];
}
</syntaxhighlight>

==== modulesPath ====

Some modules use {{ic|modulesPath}} to import NixOS libraries.

For example {{Nixpkgs Link|nixos/modules/virtualisation/digital-ocean-config.nix}}:

<syntaxhighlight lang="nix">
{ config, pkgs, lib, modulesPath, ... }:
  imports = [
    (modulesPath + "/profiles/qemu-guest.nix")
    (modulesPath + "/virtualisation/digital-ocean-init.nix")
  ];
</syntaxhighlight>

The Nix variable {{ic|modulesPath}} is parsed from the environment variable {{ic|NIX_PATH}}.

When {{ic|NIX_PATH}} is empty, Nix can throw the error {{ic|undefined variable 'modulesPath'}}.

{{ic|NIX_PATH}} should look something like this:

<pre>
$ echo $NIX_PATH | tr : '\n' 
nixpkgs=/nix/var/nix/profiles/per-user/root/channels/nixos
nixos-config=/etc/nixos/configuration.nix
/nix/var/nix/profiles/per-user/root/channels
</pre>

Here, the {{ic|modulesPath}} is {{ic|/nix/var/nix/profiles/per-user/root/channels}}.

When a Nix expression calls {{ic|import <nixpkgs>}},<br>
Nix will load {{ic|/nix/var/nix/profiles/per-user/root/channels/nixos}}.

====Module Imports vs builtins-imports====
Beginners often confuse the modules attribute {{ic|imports {{=}} [./module.nix]}} here with the Nix [https://nixos.org/manual/nix/stable/language/builtins.html#builtins-import builtins] function {{ic|import module.nix}}. The first expects a path to a file containing a NixOS module (having the same specific structure we're describing here), while the second loads whatever Nix expression is in that file (no expected structure). See [https://discourse.nixos.org/t/import-list-in-configuration-nix-vs-import-function/11372/8 this post].

{{Note|{{ic|imports}} provides the same behavior as the obsolete {{ic|require}}. There is no reason to use {{ic|require}} anymore, however it may still linger in some legacy code.}}

=== Declarations (options)===

Declarations specify a module's external interfaces.

<syntaxhighlight lang=nix>
optionName = mkOption {
  # ...
}
</syntaxhighlight>

They are created with {{ic|mkOption}}, a function accepting a set with following attributes:<ref>{{Nixpkgs Link|lib/options.nix#L51-L84}}</ref><ref>{{manual:nixos|sec=#sec-option-declarations|chapter=42.1. Option Declarations}}</ref>

<dl>
<dt><code>type</code></dt>
<dd><p>
      The type of the option. It may
      be omitted, but that’s not advisable since it may lead to errors that
      are hard to diagnose. See [[NixOS:Declaration]] for more types
</p></dd>
<dt><code>default</code></dt>
<dd><p>
      The default value used if no value is defined by any module. A default is
      not required; but if a default is not given, then users of the module
      will have to define the value of the option, otherwise an error will be
      thrown.
</p></dd>
<dt><code class="varname">example</code></dt>
<dd><p>
      An example value that will be shown in the NixOS manual.
</p></dd>
<dt><code>description</code></dt>
<dd><p>
      A textual description of the option, in DocBook format, that will be
      included in the NixOS manual.
</p></dd>
</dl>

There are also some helper Option functions:
<syntaxhighlight lang=nix>
optionName = mkEnableOption "this cool module";

#this is the same as

optionName = mkOption {
  type = lib.types.bool;
  default = false;
  example = true;
  description = "Whether to enable this cool module.";
}
</syntaxhighlight>

==== Examples ====

===== Simple Enable option =====
If you just want to be able to enable/disable a module you can define an Enable option like this:
<syntaxhighlight lang="nix">
{ lib, config, ...}: 
let cfg = config.myModule; in {
  options = {
    myModule.enable = lib.mkEnableOption "Enable Module";
  };

  config = lib.mkIf cfg.enable {
    #config contents
  }
}
</syntaxhighlight>

==== Shorthand ====
If your module has no declarations there is a shorthand:

<syntaxhighlight lang="nix">
{
  imports = [
    # Paths to other modules.
  ];

  # Config definitions.
  services.othermodule.enable = true;
  # ...
  # Notice that you can leave out the "config { }" wrapper.
}
</syntaxhighlight>

== Full Example ==

To see how modules are setup and reuse other modules in practice put {{ic|hello.nix}} in the same folder as your {{ic|configuration.nix}}:

{{file|hello.nix|nix|<nowiki>
{ lib, pkgs, config, ... }:
with lib;                      
let
  # Shorter name to access final settings a 
  # user of hello.nix module HAS ACTUALLY SET.
  # cfg is a typical convention.
  cfg = config.services.hello;
in {
  # Declare what settings a user of this "hello.nix" module CAN SET.
  options.services.hello = {
    enable = mkEnableOption "hello service";
    greeter = mkOption {
      type = types.str;
      default = "world";
    };
  };

  # Define what other settings, services and resources should be active IF
  # a user of this "hello.nix" module ENABLED this module 
  # by setting "services.hello.enable = true;".
  config = mkIf cfg.enable {
    systemd.services.hello = {
      wantedBy = [ "multi-user.target" ];
      serviceConfig.ExecStart = "${pkgs.hello}/bin/hello -g'Hello, ${escapeShellArg cfg.greeter}!'";
    };
  };
}
</nowiki>}}

The other {{ic|configuration.nix}} module can then import this {{ic|hello.nix}} module 
and decide to enable it (and optionally set other allowed settings) as follows:

{{File|configuration.nix|nix|<nowiki>
{
  imports = [ ./hello.nix ];
  ...
  services.hello = {
    enable = true;
    greeter = "Bob";
  };
}
</nowiki>}}

== Advanced Use Cases ==
=== Compatibility Issues with Different Nixpkgs Versions ===

Module options between Nixpkgs revisions can sometimes change in incompatible ways.

For example, the option {{nixos:option|services.nginx.virtualHosts.*.port}} in nixpkgs-17.03 was replaced by {{nixos:option|services.nginx.virtualHosts.*.listen}} in nixpkgs-17.09. If {{ic|configuration.nix}} has to accommodate both variants, {{ic|options}} can be inspected:

<syntaxhighlight lang="nix">
{ options, ... }: {
  services.nginx.virtualHosts.somehost = { /* common configuration */ }
    // (if builtins.hasAttr "port" (builtins.head options.services.nginx.virtualHosts.type.getSubModules).submodule.options
          then { port = 8000; }
          else { listen = [ { addr = "0.0.0.0"; port = 8000; } ]; });
}
</syntaxhighlight>

=== Abstract imports ===

To import a module that's stored ''somewhere'' (but for which you have neither an absolute nor a relative path), you can use [https://github.com/musnix/musnix#basic-usage NIX_PATH elements] or {{ic|specialArgs}} from {{Nixpkgs Link|nixos/lib/eval-config.nix}}.

This is useful for e.g. pulling modules from a git repository without adding it as a channel, or if you just prefer using paths relative to a root you can change (as opposed to the current file, which could move in the future).

<syntaxhighlight lang="nix">
let
  inherit (import <nixpkgs> {}) writeShellScriptBin fetchgit;
  yourModules = fetchgit { ... };
in rec {
  nixos = import <nixpkgs/nixos/lib/eval-config.nix> {
    modules = [ ./configuration.nix ];
    specialArgs.mod = name: "${yourModules}/${name}";
  };

  /* use NixOS here, e.g. for deployment or building an image */
}
</syntaxhighlight>

<syntaxhighlight lang="nix">
{ config, lib, pkgs, mod, ... }: {
  imports = [
    (mod "foo.nix")
  ];

  ...
}
</syntaxhighlight>

=== Using external NixOS modules ===

Some external modules provide extra functionality to the NixOS module system. You can include these modules, after making them available as a file system path (e.g. through {{ic|builtins.fetchTarball}}, by using {{ic|imports {{=}} [ `path to module`]}} in your {{ic|configuration.nix}}.

* [https://github.com/ip1981/nixsap Nixsap] - allows to run multiple instances of a service without containers.
* [https://github.com/musnix/musnix musnix] - real-time audio in NixOS.
* [https://gitlab.com/simple-nixos-mailserver/nixos-mailserver nixos-mailserver] - full-featured mail server module
* [https://github.com/xtruder/nix-profiles X-Truder Nix-profiles] - modules for Nix to quickly configure your system based on application profiles.

=== disabledModules attribute ===

You can disable modules by using the top-level attribute {{ic|disabledModules}}. This is useful for disabling modules from Nixpkgs or NixOS. This can also be used to override modules that have the same name (Ex: You want to override a module from NixOS with your own implementation). [https://github.com/NixOS/nixpkgs/blob/master/nixos/doc/manual/development/replace-modules.section.md More info]

{{ic|disabledModules}} is a top level attribute just like the {{ic|imports}} or {{ic|options}} of the module.

<syntaxhighlight lang="nix">
{ config, lib, pkgs, ... }:

{
  disabledModules = [ "./helloWorld.nix" ];

  imports =
    [ 
      ./helloWorld.nix
    ];

  #This does nothing because ./helloWorld is disabled
  services.helloWorld.enable = true;
}
</syntaxhighlight>

== Under the hood ==

The following was taken from a comment by Infinisil on Reddit:<ref>Infinisil, https://www.reddit.com/r/NixOS/comments/gdnzhy/question_how_nixos_options_works_underthehood/</ref>

A NixOS system is described by a single system derivation. {{ic|nixos-rebuild}} builds this derivation with {{Commands|$ nix-build '<nixpkgs/nixos>' -A system}} and then switches to that system with {{Commands|$ result/bin/switch-to-configuration}}

The entrypoint is the file at {{ic|'<nixpkgs/nixos>' (./default.nix)}}, which defines the {{ic|system}} attribute to be the NixOS option {{nixos:option|system.build.toplevel}}. This {{ic|toplevel}} option is the topmost level of the NixOS evaluation and it's what almost all options eventually end up influencing through potentially a number of intermediate options.

As an example:
* The high-level option {{nixos:option|services.nginx.enable}} uses the lower-level option {{nixos:option|systemd.services.nginx}}
* Which in turn uses the even-lower-level option {{ic|systemd.units."nginx.service"}}
* Which in turn uses {{ic|environment.etc."systemd/system"}}
* Which then ends up as {{ic|result/etc/systemd/system/nginx.service}} in the top-level derivation

So high-level options use lower-level ones, eventually ending up at {{nixos:option|system.build.toplevel}}.

How do these options get evaluated though? That's what the NixOS module system does, which lives in the {{ic|./lib}} directory (in {{ic|modules.nix}}, {{ic|options.nix}} and {{ic|types.nix}}). The module system can even be used without NixOS, allowing you to use it for your own option sets. Here's a simple example of this, whose {{ic|toplevel}} option you can evaluate with {{Commands|$ nix-instantiate --eval file.nix -A config.toplevel}}

<syntaxhighlight lang="nix">
let
  systemModule = { lib, config, ... }: {
    options.toplevel = lib.mkOption {
      type = lib.types.str;
    };

    options.enableFoo = lib.mkOption {
      type = lib.types.bool;
      default = false;
    };

    config.toplevel = ''
      Is foo enabled? ${lib.boolToString config.enableFoo}
    '';
  };

  userModule = {
    enableFoo = true;
  };

in (import <nixpkgs/lib>).evalModules {
  modules = [ systemModule userModule ];
}
</syntaxhighlight>

The module system itself is rather complex, but here's a short overview. A module evaluation consists of a set of "modules", which can do three things:

* Import other modules (through {{ic|imports {{=}} [ ./other-module.nix ];}})
* Declare options (through {{ic|options {{=}} { ... };}})
* Define option values (through {{ic|config {{=}} { ... };}}, or without the config key as a shorthand if you don't have imports or options)

To do the actual evaluation, there's these rough steps:

* Recursively collect all modules by looking at all {{ic|imports}} statements
* Collect all option declarations (with {{ic|options}}) of all modules and merge them together if necessary
* For each option, evaluate it by collecting all its definitions (with {{ic|config}}) from all modules and merging them together according to the options type.

Note that the last step is lazy (only the options you need are evaluated) and depends on other options itself (all the ones that influence it).

== More complex usages ==

The examples below contain:

* a child {{ic|mkOption}} inherits their default from a parent {{ic|mkOption}}
* reading default values from neighbouring {{ic|mkOption}}(s) for conditional defaults
* passing in the config, to read the {{ic|hostName}} from a submodule (email system)
* setting default values from attrset (email system)
* generating documentation for custom modules (outside of Nixpkgs). [https://discourse.nixos.org/t/franken-script-to-generate-nixos-options-docs-with-custom-modules/1674 See here]

Source:

* https://github.com/nixcloud/nixcloud-webservices/blob/master/modules/services/reverse-proxy/default.nix
* https://github.com/nixcloud/nixcloud-webservices/blob/master/modules/services/reverse-proxy/options.nix
* https://github.com/nixcloud/nixcloud-webservices/blob/master/modules/services/TLS/default.nix
* https://github.com/nixcloud/nixcloud-webservices/blob/master/modules/services/email/nixcloud-email.nix#L114

(sorry, don't have more time to make this into a nice little guide yet, but these links should be pretty good introductions into more advanced module system usages) qknight

== Developing modules ==

To test your module out, you can run the following from a local checkout of Nixpkgs with a copy of a {{ic|configuration.nix}}:
{{Commands|<nowiki>
$ nixos-rebuild build-vm --fast -I nixos-config=./configuration.nix -I nixpkgs=.
</nowiki>}}

If you're developing on top of master, this will potentially cause the compilation of lots of packages, since changes on master might not cached on cache.nixos.org yet. To avoid that, you can develop your module on top of the {{ic|nixos-unstable}} [[Channels|channel]], tracked by the eponymous branch in https://github.com/NixOS/nixpkgs:

{{Commands|
$ git checkout -b mymodule upstream/nixos-unstable
}}

=== With Flakes ===
If you're developing a module from Nixpkgs, you can try and follow the directions here: https://github.com/Misterio77/nix-starter-configs/issues/28.

If you want to develop a module from a git repo, you can use {{ic|--override-input}}. For example, if you have an input in your flake called {{ic|jovian}}, you can use

{{Commands|
$ nixos-rebuild switch --override-input jovian <path-to-url> --flake <uri>
}}

Of course, it doesn't have to be {{ic|nixos-rebuild}} in particular.
== References ==

<references />

== See also ==

* [[NixOS:extend_NixOS]]
* [[NixOS:Properties]]
* [https://discourse.nixos.org/t/best-resources-for-learning-about-the-nixos-module-system NixOS discourse, "Best resources for learning about the NixOS module system?"]
* Debian [http://wiki.debian.org/PackageConfigUpgrade Config::Model]: target configuration upgrades by abstracting the option of the configuration. Each file is a tree structure where leaves are values defined with an interpreted type.  The interpreters are defined for each meta-configuration files name {{ic|*.conf}}. Configuration files does not seems to interact with each other to make consistent configuration. They provide an UI for editing their configuration file.

[[Category:Configuration]]
[[Category:Reference]]
[[Category:NixOS]]