View source for Qt

{{expansion}}

== Development ==
If you want to develop qt applications in nixos you have to use nix-shell or direnv.
For using nix-shell just run this command in the terminal:

<code>nix-shell -p qt5Full -p qtcreator --run qtcreator</code>

Tip: if it finds no Qt Kits, <code>rm -rf ~/.config/QtProject*</code> and start again. Sometimes it finds a kit, but cannot find a suitable qt version for it, in this case you can also type <code>which qmake</code> in your nix-shell and add a new entry in the <code>QT-Versions</code> tab in <code>Tools->Options->Kits</code>.

For using direnv, create a '''shell.nix''' file in the root of your project and paste these lines into it:
<syntaxHighlight lang=nix>
# shell.nix
{ pkgs ? import <nixpkgs> {} }:
  pkgs.mkShell {
    buildInputs = [
                    pkgs.qt5.full
                    pkgs.qtcreator
                  ];
}
</syntaxHighlight>

Tip: if you want use clang-format, add '''clang-format''' to '''buildinputs''' list.

Also create '''.envrc''' file and paste: <code>use_nix</code> into it.

Happy qt coding :)


== Packaging ==

[https://nixos.org/manual/nixpkgs/stable/#sec-language-qt See] for the entry in the nixpkgs manual.

Qt applications can't be called with <code>callPackage</code>, since they expect more inputs. Namely <code>qtbase</code> and <code>wrapQtAppsHook</code>. Instead they should be called with <code>libsForQt5.callPackage</code>.

{{File|./build/default.nix|nix|<nowiki>
{ stdenv, lib, qtbase, wrapQtAppsHook }: 

stdenv.mkDerivation {
  pname = "myapp";
  version = "1.0";

  buildInputs = [ qtbase ];
  nativeBuildInputs = [ wrapQtAppsHook ]; 
}
</nowiki>}}

<syntaxHighlight lang=nix>
#nix-repl
myapp = callPackage ./build/myapp/default.nix { } # Will complain it wasn't called with qtbase, etc.
myapp = libsForQt5.callPackage ./build/myapp/default.nix { } # Should work
</syntaxHighlight>


== Projects using python (e.g. PyQt5) ==

It's possible to package a program that uses internally python and Qt (like PyQt5) by providing a python executable with the appropriate libraries like that <code>myPython = python3.withPackages (pkgs: with pkgs; [ pyqt5 ]);</code>. `<code>wrapQtAppsHook</code>` even seems  to be optional when using `mkderivation` (at least this program can be run without) since anyway it does not patch scripts.

<syntaxHighlight lang=nix>
{ mkDerivation,
  lib,
  stdenv,
  fetchFromGitHub,
  jack2,
  which,
  python3,
  qtbase,
  qttools,
  wrapQtAppsHook,
  liblo,
  git,
}:
let
  myPython = python3.withPackages (pkgs: with pkgs; [ pyqt5 liblo pyliblo pyxdg ]);
in
mkDerivation rec {
  pname = "RaySession";
  version = "0.11.1";

  src = fetchFromGitHub {
    owner = "Houston4444";
    repo = pname;
    rev = "v${version}";
    sha256 = "sha256-EbDBuOcF0JQq/LOrakb040Yfrpdi3FOB1iczQTeXBkc=";
  };

  # This patch is required to be able to create a new session, but not a problem to compile and start the program
  # patches = [ ./copy_template_writable.patch ];

  # Otherwise lrelease-qt is not found:
  postPatch = ''
   substituteInPlace Makefile \
     --replace "lrelease-qt4" "${qttools.dev}/bin/lrelease" \
     --replace '$(DESTDIR)/' '$(DESTDIR)$(PREFIX)' # Otherwise problem with installing manual etc...
  '';

  nativeBuildInputs = [
    myPython
    wrapQtAppsHook # Not really useful since it will not pack scripts. And actually it seems that it's not required?
    which
    qttools
  ];
  propagatedBuildInputs = [ myPython qtbase jack2 git ];

  # Prefix must be set correctly due to sed -i "s?X-PREFIX-X?$(PREFIX)?"
  makeFlags = [ "PREFIX=$(out)" ]; # prefix does not work since due to line "install -d $(DESTDIR)/etc/xdg/"
}
</syntaxHighlight>

Call it with
<syntaxHighlight>
{ pkgs ? import <nixpkgs> {} }:
pkgs.libsForQt5.callPackage ./derivation.nix {}
</syntaxHighlight>

For actual python applications, you may also use something like that (to test) :
<syntaxHighlight>
python3.pkgs.buildPythonApplication {
  pname = "blabla";
  version = "3.32.2";

  nativeBuildInputs = [
    wrapQtAppsHook
    ...
  ];

  dontWrapQtApps = true; # wrapQtApps won't patch script anyway. TODO: save to use if it contains executables? 

  # Arguments to be passed to `makeWrapper`, only used by buildPython*
  preFixup = ''
        qtWrapperArgs+=("''${gappsWrapperArgs[@]}")
        # You can manually patch scripts using: wrapQtApp "$out/bin/myapp". TODO: check when it's required.
  '';
}
</syntaxHighlight>

== Migrating apps from Qt5 to Qt6 ==

# Replace <code>libsForQt5.callPackage</code> with <code>qt6Packages.callPackage</code>
# Add the dependency [https://www.qt.io/blog/porting-from-qt-5-to-qt-6-using-qt5compat-library qt5compat]
# Hope for the best ; )

<code>qt5compat</code> is only needed for Qt5 projects, which are not-yet migrated to Qt6.

Maybe add libraries like <code>qtwayland</code>

Conditional blocks in qmake <code>*.pro</code> files

<syntaxHighlight lang=pro>
lessThan(QT_MAJOR_VERSION, 6) {
  # qt5, qt4, ...
  QT += x11extras
}
equals(QT_MAJOR_VERSION, 6) {
  # qt6
  QT += core-private
}
</syntaxHighlight>

See also:

* [https://doc.qt.io/qt-6/portingguide.html Porting to Qt 6]
* [https://stackoverflow.com/questions/18663331 How to check the selected version of Qt in a .pro file?]

== Deal with QML files ==

You can find [https://gist.github.com/tobiasBora/04d0febda0b3f09707b5e1b7b85390a5 here] a minimal example to use QML, cmake, nix and Qt5. There is nothing special to nix there, but note that if you provide the qml file using something like <code>qrc:///main.qml</code>, then you need to write a qrc file that lists all the resources that must be included in the qt resource manager. This file is then used to compile the resources and include them in the binary (you have to compile the binaries, either automatically with cmake or qmake, or manually using rcc). With cmake you compile it using <code>qt5_add_resources(SOURCES qml.qrc)</code> ([https://doc.qt.io/qt-5/qtcore-cmake-qt5-add-resources.html doc]) as illustrated in the above example (make sure to use a variable as the source and to reuse the same variable in <code>add_executable</code>).


== Troubleshooting ==

=== Cannot mix incompatible Qt library (version 0x_____) with this library (version 0x_____) ===

This is a known issue, see {{issue|30551}} for the current status.

Starting with the 19.09 release, the issue should be fixed by {{pull|65526}}

=== This application failed to start because it could not find or load the Qt platform plugin ??? in "" ===
==== qt4 ====
Qt4 depends on the environment variable <code>QT_PLUGIN_PATH</code> to find plugins. It is normally already
present in the environment on NixOS at least, but for example systemd user units are launched in a pretty empty environment. A solution is to use the command {{Commands|systemctl --user import-environment QT_PLUGIN_PATH}} from a sane environment. For example add it to the <code>services.xserver.displayManager.sessionCommands</code> option.

==== qt5 ====
{{warning|This recommendation is deprecated for 19.09 and up, see {{issue|65399}}. Failing packages should be updated to use <code>wrapQtAppsHook</code>.}}

Qt5 seems (?) to look for plugins in the <code>PATH</code>. This will fail from a systemd user unit for example, because their path is nearly empty by default. As an example, here is a workaround to have <code>usbguard-applet</code> launched from a systemd user unit:
{{File|/etc/nixos/configuration.nix|nix|<nowiki>
  systemd.user.services.usbguard-applet = {
    description = "USBGuard applet";
    partOf = [ "graphical-session.target" ];
    wantedBy = [ "graphical-session.target" ];
    path = [ "/run/current-system/sw/" ]; ### Fix empty PATH to find qt plugins
    serviceConfig = {
      ExecStart = "${pkgs.usbguard}/bin/usbguard-applet-qt";
    };
  };
</nowiki>}}

====  qt.qpa.plugin: Could not find the Qt platform plugin "xcb" in "" ====
Here is a concrete example: 

<pre>
qt.qpa.plugin: Could not find the Qt platform plugin "xcb" in ""
This application failed to start because no Qt platform plugin could be initialized. Reinstalling the application may fix this problem.
</pre>

The package will need to be fixed to use [the new https://github.com/NixOS/nixpkgs/issues/65399 <code>wrapQtAppsHook</code>]. The hook wraps every qt application with adding <code>QT_PLUGIN_PATH</code> and <code>XDG_DATA_DIRS</code> as well as <code>XDG_CONFIG_DIRS</code>.See [https://github.com/NixOS/nixpkgs/blob/nixos-19.09/pkgs/development/libraries/qt-5/hooks/wrap-qt-apps-hook.sh wrap-qt-apps-hook.sh in nixpkgs]

==== Debugging methods ====
As a general rule, exporting <code>QT_DEBUG_PLUGINS=1</code> make qt print where it looks for plugins.

If a plugin exists in a directory but is ignored with a message like <code>QLibraryPrivate::loadPlugin failed on "/nix/store/...-teamspeak-client-3.1.6/lib/teamspeak/platforms/libqxcb.so" : "Cannot load library /nix/store/...-client-3.1.6/lib/teamspeak/platforms/libqxcb.so: "</code> it can be that the library cannot be <code>dlopen()</code>ed because of dependencies/rpath issues and needs <code>patchelf</code>ing. Exporting <code>LD_DEBUG=libs</code> may prove helpful in this scenario.